home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Software Vault: The Gold Collection
/
Software Vault - The Gold Collection (American Databankers) (1993).ISO
/
cdr11
/
pcv05n08.zip
/
MACRO.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-06-12
|
1KB
|
66 lines
@ECHO OFF
REM NAME: MACRO.BAT
REM PURPOSE: Run Macros From File
IF (%1)==(/?) GOTO HELP
rem IF NOT EXIST C:\MACRO\*.* MD C:\MACRO > nul
IF (%1)==() GOTO MISSING
IF (%1)==(D) GOTO DISPLAY
IF (%1)==(d) GOTO DISPLAY
IF (%1)==(ABC123XYZ) GOTO SHOWTHEM
IF (%2)==() GOTO RUN
FOR %%J IN (0 1 2 3 4 5 6 7 8 9) DO IF (%1)==(%%J) GOTO DEFINE
GOTO ERROR1
:ERROR1
ECHO You entered an invalid parameter
GOTO MISSING
:ERROR2
ECHO Commands are limited to nine words--yours was too long
ECHO Everything from and including %9 was not recorded
GOTO END
:ERROR3
ECHO Macro (%1) does not exist
GOTO MISSING
:RUN
IF NOT EXIST C:\MACRO\%1.BAT GOTO ERROR3
CALL C:\MACRO\%1.BAT
GOTO END
:MISSING
ECHO To define a macro, enter a number followed by commands
ECHO (Valid numbers are 0 through 9)
ECHO To run an existing macro, enter its number
ECHO The available macros are:
GOTO DISPLAY
:DISPLAY
FOR %%J IN (0 1 2 3 4 5 6 7 8 9) DO CALL MACRO ABC123XYZ %%J
GOTO END
:SHOWTHEM
IF NOT EXIST C:\MACRO\%2.BAT GOTO END
ECHO --%2--
TYPE C:\MACRO\%2.BAT | FIND /V "@ECHO OFF"
GOTO END
:DEFINE
SHIFT
ECHO @ECHO OFF > C:\MACRO\%0.BAT
ECHO %1 %2 %3 %4 %5 %6 %7 %8 %9 >> C:\MACRO\%0.BAT
SHIFT
IF NOT (%9)==() GOTO ERROR2
GOTO END
:HELP
ECHO MACRO.BAT enables you to define up to ten macros.
ECHO They are stored as batch files in the directory C:\MACRO
GOTO END
:END